package {
   
   /**
    *
    *    Auteur: Vincent Helwig
    *    Date: 30.10.2008
    *    Website: http://www.tsoin.com
    *    Description: Clavier de Piano / SampleDataEvent
    *
    **/
   
   import flash.display.MovieClip;
   import flash.media.Sound;
   import flash.events.MouseEvent;
   import flash.events.SampleDataEvent;
   import flash.media.SoundChannel;

   [SWF(width = "542", height = "190", backgroundColor = "#dfdede", framerate = "30")]

   public class SoundSampleDataEvent extends MovieClip {

      private var _son:Sound
      private var phase:Number = 0;
      private var freq:Number = 440;
      private const PI2:Number = Math.PI * 2;
      private var soundChannelObject:SoundChannel = new SoundChannel();
      private var _clavier:Clavier;

      public function SoundSampleDataEvent() {

         _son = new Sound();

         _clavier = new Clavier(Clavier.OCTAVE3);
         _clavier.x = 5;
         _clavier.y = 5;
         _clavier.addEventListener( MouseEvent.MOUSE_DOWN, onNoteDown );
         _clavier.addEventListener( MouseEvent.CLICK, onNoteUp );
         addChild(_clavier);

         _clavier = new Clavier(Clavier.OCTAVE4);
         _clavier.x = 271;
         _clavier.y = 5;
         _clavier.addEventListener( MouseEvent.MOUSE_DOWN, onNoteDown );
         _clavier.addEventListener( MouseEvent.CLICK, onNoteUp );
         addChild(_clavier);

      }

      private function onNoteDown(e:MouseEvent):void {
         freq = e.target.frequence;
         _son.addEventListener( SampleDataEvent.SAMPLE_DATA, onSample);
         soundChannelObject = _son.play();
      }

      private function onNoteUp(e:MouseEvent):void {
          _son.removeEventListener( SampleDataEvent.SAMPLE_DATA, onSample);
          soundChannelObject.stop();
      }

      public function onSample(e:SampleDataEvent):void {
         var smpl:Number;
         var w:Number = PI2 * freq / 44000;

         for (var i:int = 0; i < 8192; ++i) {
            phase += w;
             if (phase > PI2) { phase -= PI2; }
            smpl = Math.sin(phase);

            e.data.writeFloat(smpl);
            e.data.writeFloat(smpl);
         }

      }

   }

}